Beispiele

Weitere Beispiele siehe auch APIEngine V1.90 Demoversion.

Beispiel 1: Erstellen von 2 Dokumenten in einer Datenbank und Anlegen der Felder FORM, SUBJECT und BODY:

DBHANDLE:=@OpenDB("TEST.NSF");

IF (@GetDataTyp(DBHANDLE)="DH")
{
DOKUMENT1:=@CreateNote(DBHANDLE;DOKUMENT1);
DOKUMENT2:=@CreateNote(DBHANDLE;DOKUMENT2);

FORM[DOKUMENT1] :="TEST";
SUBJECT[DOKUMENT1]:="DOKUMENT Nr. 1";
BODY[DOKUMENT1] :="Inhalt des 1. Dokumentes";

FORM[DOKUMENT2] :="TEST";
SUBJECT[DOKUMENT2]:="DOKUMENT Nr. 2";
BODY[DOKUMENT2] :="Inhalt des 2. Dokumentes";

DOKUMENT1:=@CloseNote(DOKUMENT1;1);
DOKUMENT2:=@CloseNote(DOKUMENT2;1);

DBHANDLE :=@CloseDB(DBHANDLE);
}
ELSE
{
@LogReport("Datenbank kann nicht geöffnet werden!");
}

Beispiel 2: Selektieren von Dokumenten in einer Datenbank anhand einer Selektionsformel und ändern des Feldinhaltes von SUBJECT:

DBHANDLE:=@OpenDB("TEST.NSF");

IF (@GetDataTyp(DBHANDLE)="DH")
{
SELEKTIONSFORMEL:="SELECT Form=\"TEST\"";
DOKUMENTLISTE :=@ScanDB(DBHANDLE;SELEKTIONSFORMEL;@AnyAllDay;1);

IF (!@IsError(DOKUMENTLISTE))
{
N:=1;

WHILE (N<=@Elements(DOKUMENTLISTE))
{
DOKUMENTID:=@GetListElement(DOKUMENTLISTE;N);
DOKUMENTNX:=@OpenNoteByID(DBHANDLE;DOKUMENTID;DOKUMENTNX);

SUBJECT[DOKUMENTNX]:="Allgemeine Änderung des Betreffs";

DOKUMENTNX:=@CloseNote(DOKUMENTNX;1);
@Increment(N);
}
}
ELSE
{
@LogReport("Fehler beim Suchen der Dokumente");
}

DBHANDLE :=@CloseDB(DBHANDLE);
}
ELSE
{
@LogReport("Datenbank kann nicht geöffnet werden!");
}

Beispiel 3: Suchen nach einer Kategorie in einer Ansicht und öffnen des 1. Dokumentes in dieser Kategorie. Ändern des Feldinhaltes von SUBJECT:

DBHANDLE:=@OpenDB("TEST.NSF");

IF (@GetDataTyp(DBHANDLE)="DH")
{
ANSICHT:=@OpenView(DBHANDLE;"Name der Ansicht");

IF (@GetDataTyp(ANSICHT)="VH")
{
POSITION :=@BuildList(0;10);
KATEGORIE:="Allgemeine Info";

POSITION :=@FindCategoryByName(ANSICHT;KATEGORIE;POSITION);

IF (!@IsError(POSITION))
{
DOC:=@OpenNoteByPosition(DBHANDLE;ANSICHT;POSITION;DOC);
IF (@GetDataTyp(DOC)="NH")
{
SUBJECT[DOC]:="Änderung des Betreffs";
DOC:=@CloseNote(DOC;1);
}
ELSE
{
@LogReport("Dokument kann nicht geöffnet werden!");
}
}
ELSE
{
@LogReport("Kategorie wurde nicht gefunden!");
}

ANSICHT:=@CloseView(ANSICHT);
}
ELSE
{
@LogReport("Ansicht kann nicht geöffnet werden!");
}

DBHANDLE:=@CloseDB(DBHANDLE);
}
ELSE
{
@LogReport("Datenbank kann nicht geöffnet werden!");
}

Beispiel 4: Suchen nach einer Kategorie in einer Ansicht und öffnen aller Dokumentes in dieser Kategorie. Ändern des Feldinhaltes von SUBJECT:

DBHANDLE:=@OpenDB("TEST.NSF");

IF (@GetDataTyp(DBHANDLE)="DH")
{
ANSICHT:=@OpenView(DBHANDLE;"Name der Ansicht");

IF (@GetDataTyp(ANSICHT)="VH")
{
POSITION :=@BuildList(0;10);
KATEGORIE:="Allgemeine Info";

POSITION :=@FindCategoryByName(ANSICHT;KATEGORIE;POSITION);

IF (!@IsError(POSITION))
{
ANZAHL_DOKUMENTE:=@GetListElement(POSITION;10);
N:=1;

WHILE (N<=ANZAHL_DOKUMENTE)
{
DOC:=@OpenNoteByPosition(DBHANDLE;ANSICHT;POSITION;DOC);
IF (@GetDataTyp(DOC)="NH")
{
SUBJECT[DOC]:="Änderung des Betreffs";
DOC:=@CloseNote(DOC;1);
}
ELSE
{
@LogReport("Dokument kann nicht geöffnet werden!");
}
@CountListElement(POSITION;3;1);
@Increment(N);
}
}
ELSE
{
@LogReport("Kategorie wurde nicht gefunden!");
}

ANSICHT:=@CloseView(ANSICHT);
}
ELSE
{
@LogReport("Ansicht kann nicht geöffnet werden!");
}

DBHANDLE:=@CloseDB(DBHANDLE);
}
ELSE
{
@LogReport("Datenbank kann nicht geöffnet werden!");
}